Regiux

Fork

{
  description = "Packages built with RPython";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/release-23.05";
    flake-utils.url = "github:numtide/flake-utils";
    rpypkgs = {
      url = "github:rpypkgs/rpypkgs";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
  };

  outputs = { self, nixpkgs, flake-utils, rpypkgs }:
    let
      # The systems where RPython has been tested to work.
      testedSystems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
    in flake-utils.lib.eachSystem testedSystems (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          # Not free for corporate use!
          config.allowUnfree = true;
        };
        regiux = rpypkgs.lib.${system}.mkRPythonDerivation {
          entrypoint = "main.py";
          binName = "main-c";
          binInstallName = "rix";
          optLevel = "2";
          withLibs = ls: with ls; [ appdirs rply ];
        } {
          pname = "regiux";
          version = "2024";

          src = ./.;

          meta = {
            description = "A fast implementation of the Nix expression language";
            license = pkgs.lib.licenses.cc-by-nc-sa-40;
          };
        };
      in {
        packages.default = regiux;
        devShells.default = pkgs.mkShell {
          packages = [];
        };
      }
    );
}